これとは異なる方法で複数の値を返す手段として、Tuple型(タプル)を利用することもできます。　Tuple型は複数の値をひとまとめにするという点は配列と似ていますが、異なる型同士でもまとめることができる点で配列とは異なります。　これにより、配列では値を複数返す場合でも同じ型に限られるのに対し、Tuple型を用いれば型の異なる複数の値を返すことができます。

Tuple型を使って合計と平均を返すメソッド
Imports System

Class Sample
  ' 引数で与えられた配列の合計と平均を求めるメソッド
  ' 合計はTuple.Item1, 平均はTuple.Item2に格納する
  Shared Function SumAvr(ByVal arr() As Integer) As Tuple(Of Long, Double)

    Dim sum As Long = 0L

    For Each val As Integer In arr
      sum += val
    Next

    Dim avr As Double = sum / arr.Length

    ' Item1にsum, Item2にavrの値を格納したTupleを作成して返す
    Return Tuple.Create(sum, avr)

  End Function

  Shared Sub Main()

    ' この配列内の要素の合計と平均を求めたい
    Dim arr() As Integer = New Integer() {2, 5, 3, 8, 4}

    Dim ret As Tuple(Of Long, Double) = SumAvr(arr)

    Console.WriteLine("合計 = {0}", ret.Item1)
    Console.WriteLine("平均 = {0}", ret.Item2)

  End Sub
End Class
実行結果
合計 = 22
平均 = 4.4

このように、配列と違ってTuple型では型の異なる値をひとまとめにできる利点がある一方、Tuple型では格納されている値を参照するのにItem1, Item2といったメンバ名で参照する必要があるため、配列同様に格納されている値の意味があいまいになるという欠点もあります。

比較用の参考として、JavaScriptなどいくつかのスクリプト言語では以下のようなコードを記述することができます。

function SumAvr(arr) {
  var sum = 0;

  for (var i = 0; i < arr.length; i++) {
    sum += arr[i];
  }

  var avr = sum / arr.length;

  return [sum, avr];
}

var sum, avr;

[sum, avr] = SumAvr([2, 5, 3, 8, 4]);