Imports System
Imports System.Collections.Generic

Class Sample
  Shared Sub Main()
    ClassifyType(GetType(Integer))
    ClassifyType(GetType(String))
    ClassifyType(GetType(Double()))
    ClassifyType(GetType(DateTime))
    ClassifyType(GetType(KeyValuePair(Of ,)))
    ClassifyType(GetType(DayOfWeek))
    ClassifyType(GetType(List(Of)))
    ClassifyType(GetType(ICloneable))
    ClassifyType(GetType(IEnumerable(Of)))
    ClassifyType(GetType(EventHandler))
    ClassifyType(GetType(Action(Of)))
  End Sub

  Shared Sub ClassifyType(ByVal t As Type)
    Console.Write("{0}: ", t.FullName)

    If t.IsValueType Then
      If t.IsEnum Then
        Console.WriteLine("列挙体")
      Else
        If t.IsPrimitive Then
          Console.WriteLine("値型(プリミティブ)")
        Else
          If t.IsGenericType Then Console.Write("ジェネリック")

          Console.WriteLine("構造体")
        End If
      End If
    Else
      If t.IsArray Then
        Console.WriteLine("配列型")
      Else
        If t.IsGenericType Then Console.Write("ジェネリック")

        If t.IsInterface Then
          Console.WriteLine("インターフェイス型")
        Else
          If IsDelegate(t) Then
            Console.WriteLine("デリゲート型")
          Else
            Console.WriteLine("クラス型")
          End If
        End If
      End If
    End If
  End Sub

  Shared Function IsDelegate(ByVal t As Type) As Boolean
    Return t.IsSubclassOf(GetType([Delegate])) OrElse t.Equals(GetType([Delegate]))
  End Function
End Class

System.Int32: 値型(プリミティブ)
System.String: クラス型
System.Double[]: 配列型
System.DateTime: 構造体
System.Collections.Generic.KeyValuePair`2: ジェネリック構造体
System.DayOfWeek: 列挙体
System.Collections.Generic.List`1: ジェネリッククラス型
System.ICloneable: インターフェイス型
System.Collections.Generic.IEnumerable`1: ジェネリックインターフェイス型
System.EventHandler: デリゲート型
System.Action`1: ジェネリックデリゲート型