Imports System
Imports System.Reflection

' 型パラメータTCを取るジェネリック型
Class C(Of TC)
  ' ジェネリック型の型パラメータTCを引数にとるメソッド
  Public Overloads Sub M(ByVal _tc As TC)
    Console.WriteLine($"M({GetType(TC)} = {_tc})")
  End Sub

  ' ジェネリック型の型パラメータTCと、メソッドの型パラメータを引数TMにとるジェネリックメソッド
  Public Overloads Sub M(Of TM)(ByVal _tc As TC, ByVal _tm As TM)
    Console.WriteLine($"M({GetType(TC)} = {_tc}, {GetType(TM)} = {_tm})")
  End Sub
End Class

Class Sample
  Shared Sub Main()
    ' ジェネリック型定義(C(Of))の型情報ではインスタンス作成・メソッド呼び出しはできない
    ' MakeGenericTypeメソッドで具体的な型(C(Of String)など)に型付けする必要がある
    Dim t As Type = GetType(C(Of)).MakeGenericType(GetType(String))
    ' Dim t As Type = GetType(C(Of String)) ' あるいは型付けされた状態の型情報を取得する
    Dim inst As Object = Activator.CreateInstance(t)

    ' 引数リストが(TC)のメソッドMを取得する
    Dim m1 As MethodInfo = t.GetMethod("M", types := New Type() {
      GetType(String) ' 型パラメータTCはMakeGenericTypeでStringに型付けされている
    })

    ' メソッドC(Of String).M(String)を呼び出す
    m1.Invoke(inst, New Object() {"arg"})

    ' 引数リストが(TC, TM)のメソッドMを取得する
    Dim m2 As MethodInfo = t.GetMethod("M",
      genericParameterCount := 1, ' 型パラメータが1つのジェネリックメソッド
      New Type() {
        GetType(String),                    ' 型パラメータTCはMakeGenericTypeでStringに型付けされている
        Type.MakeGenericMethodParameter(0)  ' 型パラメータTMに対応する、ジェネリックメソッドの0番目の型パラメータを表すTypeを指定
      }
    )
    ' MakeGenericMethodを呼び出して、型付けされた状態のMethodInfoを作成する
    Dim m2g As MethodInfo = m2.MakeGenericMethod(
      GetType(Integer) ' 上記の0番目の型パラメータ(TM)を、Integerに型付けする
    )

    ' メソッドC(Of String).M(Of Integer)(String, Integer)を呼び出す
    m2g.Invoke(inst, New Object() {"arg", 42})
  End Sub
End Class

M(System.String = arg)
M(System.String = arg, System.Int32 = 42)