Imports System
Imports System.Text.RegularExpressions

Class Sample
  ' マッチした箇所に置き換える文字列を返すメソッド
  Shared Function ChangeExtension(ByVal m As Match) As String
    ' 引数mにはRegex.Replaceメソッドの呼び出しでマッチした箇所が設定されている

    If m.Value.EndsWith(".bak")
      ' マッチした箇所が".bak"で終わる場合は、そのままにする
      Return m.Value
    Else
      ' そうでなければ、".bak"を追加する
      Return m.Value + ".bak"
    End If
  End Function

  Shared Sub Main()
    Dim files() As String = New String() { _
      "sample.txt", _
      "sample.txt.bak", _
      "sample.cs", _
      "test.txt", _
      "test.jpeg", _
      "README" _
    }

    For Each file As String In files
      Console.Write("{0,-20} => ", file)

      ' 正規表現にマッチした箇所をメソッドChangeExtensionが返す結果で置換する
      Dim bakFile As String = Regex.Replace(file, "\..*", AddressOf ChangeExtension)

      Console.WriteLine(bakFile)
    Next
  End Sub
End Class

sample.txt           => sample.txt.bak
sample.txt.bak       => sample.txt.bak
sample.cs            => sample.cs.bak
test.txt             => test.txt.bak
test.jpeg            => test.jpeg.bak
README               => README