Imports System
Imports System.IO
Imports System.Security.Cryptography

Class Sample
  Shared Sub Main(ByVal args As String())
    ' コマンドライン引数に-dもしくは--decodeが指定されている場合はデコードを行う
    Dim decode As Boolean = false

    For Each arg As String In args
      If arg = "-d" OrElse arg = "--decode" Then decode = True
    Next

    Dim input, output As Stream

    If decode Then
      ' BASE64デコードする場合

      ' 標準入力から読み込みを行い、FromBase64TransformによってBASE64デコードを行うCryptoStreamを入力元ストリームとする
      input = New CryptoStream(Console.OpenStandardInput(), New FromBase64Transform(), CryptoStreamMode.Read)

      ' 標準出力を出力先ストリームとする
      output = Console.OpenStandardOutput()
    Else
      ' BASE64エンコードする場合

      ' 標準入力を入力元ストリームとする
      input = Console.OpenStandardInput()

      ' ToBase64TransformによってBASE64エンコードを行い、標準出力へ書き込むCryptoStreamを出力先ストリームとする
      output = new CryptoStream(Console.OpenStandardOutput(), new ToBase64Transform(), CryptoStreamMode.Write)
    End If

    ' 入力元ストリームの内容を出力先ストリームに'コピー'する
    ' (コピーを行う際、CryptoStreamによってデコード/エンコード処理が行われる)
    input.CopyTo(output)

    output.Close()
  End Sub
End Class

>type sample.txt
Hello, world!

>type sample.txt | sample.exe
SGVsbG8sIHdvcmxkIQo=

>type sample.txt | sample.exe | sample.exe -d
Hello, world!