CompareOptionsのうち、IgnoreCase, IgnoreKanaType, IgnoreWidthはそれぞれ大文字小文字、ひらがなとカタカナ、全角と半角を区別しないで比較するように指定します。　これらの値や他の値と組み合わせて使用することも出来ます。

CompareOptions.IgnoreCase・IgnoreKanaType・IgnoreWidthを指定して大文字小文字・ひらがなカタカナ・全角半角を区別せずに比較する
Imports System
Imports System.Globalization
Imports System.Threading

Class Sample
  Shared Sub Main()
    Console.WriteLine(Thread.CurrentThread.CurrentCulture)

    Compare("abc", "ABC", CompareOptions.None)
    Compare("abc", "ABC", CompareOptions.IgnoreCase)
    Compare("abc", "ａｂｃ", CompareOptions.IgnoreWidth)
    Compare("abc", "ＡＢＣ", CompareOptions.IgnoreCase)
    Compare("abc", "ＡＢＣ", CompareOptions.IgnoreCase Or CompareOptions.IgnoreWidth)

    Console.WriteLine()

    Compare("あいうえお", "アイウエオ", CompareOptions.None)
    Compare("あいうえお", "アイウエオ", CompareOptions.IgnoreKanaType)
    Compare("ｱｲｳｴｵ", "アイウエオ", CompareOptions.None)
    Compare("ｱｲｳｴｵ", "アイウエオ", CompareOptions.IgnoreWidth)
    Compare("ｱｲｳｴｵ", "あいうえお", CompareOptions.IgnoreKanaType)
    Compare("ｱｲｳｴｵ", "あいうえお", CompareOptions.IgnoreKanaType Or CompareOptions.IgnoreWidth)
  End Sub

  Private Shared Sub Compare(ByVal s1 As String, ByVal s2 As String, ByVal options As CompareOptions)
    Console.WriteLine("{0} {1} : {2,2} ({3:f})", s1, s2, String.Compare(s1, s2, Thread.CurrentThread.CurrentCulture, options), options)
  End Sub
End Class
実行結果
ja-JP
abc ABC : -1 (None)
abc ABC :  0 (IgnoreCase)
abc ａｂｃ :  0 (IgnoreWidth)
abc ＡＢＣ : -1 (IgnoreCase)
abc ＡＢＣ :  0 (IgnoreCase, IgnoreWidth)

あいうえお アイウエオ :  1 (None)
あいうえお アイウエオ :  0 (IgnoreKanaType)
ｱｲｳｴｵ アイウエオ : -1 (None)
ｱｲｳｴｵ アイウエオ :  0 (IgnoreWidth)
ｱｲｳｴｵ あいうえお : -1 (IgnoreKanaType)
ｱｲｳｴｵ あいうえお :  0 (IgnoreKanaType, IgnoreWidth)