PropertyInfo.GetValue/SetValueメソッドを使うとプロパティの値の取得・設定を行うことができます。　インデクサ(既定のプロパティ、引数を持つプロパティ)に対する値の設定・取得もこのメソッドで行います。

.NET Framework 4.0以前の場合、PropertyInfo.GetValue/SetValueメソッドでは引数objの他に引数indexも指定する必要があります。　この引数はプロパティがインデクサの場合にインデックスとして使用される値を指定するためのものです。　プロパティがインデクサでない場合は引数indexにnull/Nothingを指定します。

.NET Framework 4.5以降では引数indexを必要としないオーバーロードが用意されているため、インデクサではないプロパティではインデックスの指定を省略することができます。

PropertyInfoを使ってプロパティの値を取得・設定する
Imports System
Imports System.Reflection

Class C
  Public Property P As Integer
End Class

Class Sample
  Shared Sub Main()
    Dim t As Type = GetType(C)

    Dim inst As Object = Activator.CreateInstance(t)

    ' プロパティPのPropertyInfoを取得する
    Dim p As PropertyInfo = t.GetProperty("P")

    ' プロパティに値42を設定する
    p.SetValue(inst, 42) ' .NET Framework 4.5以降の場合
    'p.SetValue(inst, 42, Nothing) ' .NET Framework 4.0以前の場合

    ' プロパティの値を取得する
    Console.WriteLine("P = {0}", p.GetValue(inst)) ' .NET Framework 4.5以降の場合
    'Console.WriteLine("P = {0}", p.GetValue(inst, Nothing)) ' .NET Framework 4.0以前の場合
  End Sub
End Class
実行結果
P = 42

PropertyInfoを使ってインデクサの値を取得・設定する場合は、インデックスを指定する必要がある以外はプロパティの場合と同様です。

ただし、C#では特に指定しない場合、インデクサの名前はデフォルトでItemとなりますが、IndexerName属性によって変更可能である点に注意してください。

プロパティ・インデクサの参照の結果例外が発生した場合、例外はTargetInvocationExceptionにラップされた上でスローされます。　TargetInvocationExceptionから実際にスローされた例外を取得する方法については§.TargetInvocationException、TargetInvocationExceptionにラップせずにスローさせる方法については§.BindingFlags.DoNotWrapExceptionsを参照してください。