Imports System
Imports System.Reflection

Class C
  Public Overloads Sub M(ByVal x As Integer)
  End Sub

  Public Overloads Sub M(Of T)(ByVal _t As T)
  End Sub

  Public Overloads Sub M(Of U, V)(ByVal _u As U, ByVal _v As V)
  End Sub
End Class

Class Sample
  Shared Sub Main()
    Dim t As Type = GetType(C)

    ' メソッド名のみでは対象が限定できないため、AmbiguousMatchExceptionとなる
    'Dim ma As MethodInfo = t.GetMethod("M")

    ' 引数リストが(Integer)のメソッドMを取得する
    Dim m1 As MethodInfo = t.GetMethod("M", New Type() {GetType(Integer)})

    ' 引数リストが(Long)のメソッドMを取得しようとする
    ' M(Of T)のTをLongに型付けしたものが取得されるのではなく、M(Long)を取得しようとするが、存在しないため、Nothingが返される
    Dim m2 As MethodInfo = t.GetMethod("M", New Type() {GetType(Long)})

    ' 型パラメータTをとり、引数リストが(T)のメソッドMを取得する
    ' GetMethodの引数genericParameterCountに型パラメータの数として1を指定し、
    ' 引数リストtypesにはType.MakeGenericMethodParameterメソッドで0番目の型パラメータに対応する型を作成して指定する
    Dim m3 As MethodInfo = t.GetMethod(
      "M", ' 名前が"M"のメソッドを対象とする
      genericParameterCount := 1, ' 型パラメータの数が1のものを対象とする
      types := New Type() {
        Type.MakeGenericMethodParameter(0) ' Type.MakeGenericMethodParameterメソッドで0番目の型パラメータ(T)を表す型を作成して、引数リストとして指定する
      }
    )

    ' 型パラメータU, Vをとり、引数リストが(U, V)のメソッドMを取得する
    Dim m4 As MethodInfo = t.GetMethod(
      "M", ' 名前が"M"のメソッドを対象とする
      genericParameterCount := 2, ' 型パラメータの数が2のものを対象とする
      types := New Type() {
        Type.MakeGenericMethodParameter(0), ' 0番目の型パラメータ(U)を表す型
        Type.MakeGenericMethodParameter(1)  ' 1番目の型パラメータ(V)を表す型
      }
    )

    Console.WriteLine($"{NameOf(m1)} = {m1}")
    Console.WriteLine($"{NameOf(m2)} = {m2}")
    Console.WriteLine($"{NameOf(m3)} = {m3}")
    Console.WriteLine($"{NameOf(m4)} = {m4}")
  End Sub
End Class

m1 = Void M(Int32)
m2 = 
m3 = Void M[T](T)
m4 = Void M[U,V](U, V)