Imports System
Imports System.Reflection

' 2つの型パラメータTCx, TCyを取るジェネリック型
Class C(Of TCx, TCy)
  ' ジェネリック型の型パラメータを引数にとるメソッド
  Public Overloads Sub M(ByVal _tcx As TCx)
  End Sub

  Public Overloads Sub M(ByVal _tcx As TCx, ByVal _tcy As TCy)
  End Sub

  ' ジェネリック型の型パラメータと、メソッドの型パラメータを引数にとるジェネリックメソッド
  Public Overloads Sub M(Of TMx)(ByVal _tcx As TCx, ByVal _tmx As TMx)
  End Sub

  Public Overloads Sub M(Of TMx, TMy)(ByVal _tcy As TCy, ByVal _tmx As TMx, ByVal _tmy As TMy)
  End Sub
End Class

Class Sample
  Shared Sub Main()
    Dim t As Type = GetType(C(Of ,))

    ' 引数リストが(TCx)のメソッドを取得する
    Dim m1 As MethodInfo = t.GetMethod("M", types := New Type() {
      t.GetGenericArguments()(0) ' 型パラメータTCx(ジェネリック型C(Of ,)の0番目の型パラメータ)
    })

    ' 引数リストが(TCx, TCy)のメソッドを取得する
    Dim m2 As MethodInfo = t.GetMethod("M", types := New Type() {
      t.GetGenericArguments()(0), ' 型パラメータTCx(ジェネリック型C(Of ,)の0番目の型パラメータ)のType
      t.GetGenericArguments()(1)  ' 型パラメータTCy(ジェネリック型C(Of ,)の1番目の型パラメータ)のType
    })

    ' 引数リストが(TCx, TMx)のメソッドを取得する
    Dim m3 As MethodInfo = t.GetMethod("M",
      genericParameterCount := 1, ' 型パラメータが1つのジェネリックメソッド
      New Type() {
        t.GetGenericArguments()(0),         ' 型パラメータTCx(ジェネリック型C(Of ,)の0番目の型パラメータ)のType
        Type.MakeGenericMethodParameter(0)  ' 型パラメータTMx(ジェネリックメソッドM(Of)の0番目の型パラメータ)のType
      }
    )

    ' 引数リストが(TCy, TMx, TMy)のメソッドを取得する
    Dim m4 As MethodInfo = t.GetMethod("M",
      genericParameterCount := 2, ' 型パラメータが2つのジェネリックメソッド
      New Type() {
        t.GetGenericArguments()(1),         ' 型パラメータTCy(ジェネリック型C(Of ,)の1番目の型パラメータ)のType
        Type.MakeGenericMethodParameter(0), ' 型パラメータTMx(ジェネリックメソッドM(Of ,)の0番目の型パラメータ)のType
        Type.MakeGenericMethodParameter(1)  ' 型パラメータTMy(ジェネリックメソッドM(Of ,)の1番目の型パラメータ)のType
      }
    )

    Console.WriteLine($"{NameOf(m1)} = {m1}")
    Console.WriteLine($"{NameOf(m2)} = {m2}")
    Console.WriteLine($"{NameOf(m3)} = {m3}")
    Console.WriteLine($"{NameOf(m4)} = {m4}")
  End Sub
End Class

m1 = Void M(TCx)
m2 = Void M(TCx, TCy)
m3 = Void M[TMx](TCx, TMx)
m4 = Void M[TMx,TMy](TCy, TMx, TMy)