Option Infer On

Imports System
Imports System.Diagnostics
Imports System.IO

Class Sample
  Shared Sub Main()
    ' 子プロセスを起動するためのProcessを作成
    Using child As New Process
      ' child.exeを子プロセスとして起動する
      child.StartInfo.FileName = "child.exe"

      ' シェルを使用せず子プロセスを起動する
      ' (リダイレクトするために必要)
      ' ⚠.NET Core/.NET 5以降ではデフォルトでFalseとなっている
      child.StartInfo.UseShellExecute = False

      ' 起動した子プロセスの標準出力・標準エラーをリダイレクトする
      child.StartInfo.RedirectStandardOutput = True
      child.StartInfo.RedirectStandardError = True

      ' リダイレクトした標準出力の内容を受信するイベントハンドラを設定する
      AddHandler child.OutputDataReceived, Sub(sender, e)
        ' 子プロセスの標準出力から受信した内容を自プロセスの標準出力に書き込む
        Console.WriteLine($"<stdout> {If(e.Data Is Nothing, "(end of stream)", e.Data)}")
      End Sub
      ' リダイレクトした標準エラーの内容を受信するイベントハンドラを設定する
      AddHandler child.ErrorDataReceived, Sub(sender, e)
        ' 子プロセスの標準出力から受信した内容を自プロセスの標準出力に書き込む
        Console.WriteLine($"<stderr> {If(e.Data Is Nothing, "(end of stream)", e.Data)}")
      End Sub

      ' プロセスを起動する
      child.Start()

      ' 標準出力・標準エラーの非同期読み込みを開始する
      child.BeginOutputReadLine()
      child.BeginErrorReadLine()

      ' 子プロセスの終了を待機する
      Do Until child.WaitForExit(250)
        ' 終了するまでの間、250ミリ秒毎に待機中のメッセージを表示する
        Console.WriteLine("(waiting)")
      Loop
    End Using
  End Sub
End Class

Imports System

Class Sample
  Shared Sub Main()
    ' 100ミリ秒おきに、標準出力と標準エラーに出力する
    For i As Integer = 0 To 5
      If i Mod 2 = 0 Then
        Console.Error.WriteLine("Hello, stderr!")
      Else
        Console.WriteLine("Hello, stdout!")
      End If

      System.Threading.Thread.Sleep(100)
    Next
  End Sub
End Class