Option Infer On

Imports System
Imports System.Diagnostics
Imports System.IO

Class Sample
  Shared Sub Main()
    ' 子プロセスを起動するためのProcessを作成
    Using child As New Process
      ' child.exeを子プロセスとして起動する
      child.StartInfo.FileName = "child.exe"

      ' シェルを使用せず子プロセスを起動する
      ' (リダイレクトするために必要)
      ' ⚠.NET Core/.NET 5以降ではデフォルトでFalseとなっている
      child.StartInfo.UseShellExecute = False

      ' 起動した子プロセスの標準出力をリダイレクトする
      child.StartInfo.RedirectStandardOutput = True

      ' リダイレクトした標準出力の内容を受信するイベントハンドラを設定する
      AddHandler child.OutputDataReceived, Sub(sender, e)
        ' 子プロセスの標準出力から受信した内容を自プロセスの標準出力に書き込む
        Console.WriteLine($"<stdout> {If(e.Data Is Nothing, "(end of stream)", e.Data)}")
      End Sub

      ' プロセスを起動する
      child.Start()

      ' 標準出力の非同期読み込みを開始する
      child.BeginOutputReadLine()
      Console.WriteLine("(begin)")

      ' 500ミリ秒待機する
      System.Threading.Thread.Sleep(500)

      ' 標準出力の非同期読み込みを中断する
      child.CancelOutputRead()
      Console.WriteLine("(cancel)")

      ' 500ミリ秒待機する (この間も標準出力の非同期読み込みは継続する)
      System.Threading.Thread.Sleep(500)

      ' 標準出力の非同期読み込みを再度開始する
      child.BeginOutputReadLine()
      Console.WriteLine("(begin)")

      ' 子プロセスの終了を待機する
      child.WaitForExit()
    End Using
  End Sub
End Class

Imports System

Class Sample
  Shared Sub Main()
    ' 100ミリ秒おきにカウントアップして標準出力に出力する
    For i As Integer = 0 To 14
      Console.WriteLine(i)

      System.Threading.Thread.Sleep(100)
    Next
  End Sub
End Class