Imports System
Imports System.Diagnostics
Imports System.IO
Imports System.Text

Class Sample
  Shared Sub Main()
    ' 子プロセスchild.exeの起動オプション
    Dim psi As New ProcessStartInfo("child.exe")
    ' シェルを使用せず子プロセスを起動する
    ' (リダイレクトするために必要)
    ' ⚠.NET Core/.NET 5以降ではデフォルトでFalseとなっている
    psi.UseShellExecute = False
    ' 起動した子プロセスの標準入出力をリダイレクトする
    psi.RedirectStandardInput = True
    psi.RedirectStandardOutput = True

    ' 子プロセスを起動する
    Using child As Process = Process.Start(psi)
      ' リダイレクトされた子プロセスの標準入出力を取得する
      Dim stdin As StreamWriter = child.StandardInput
      Dim stdout As StreamReader = child.StandardOutput

      ' BaseStreamを参照して標準入出力のStreamを取得し、
      ' BinaryWriter/BinaryReaderを作成する
      Using stdinWriter As New BinaryWriter(stdin.BaseStream)
        ' 6バイトのバイナリデータを標準入力へ書き込む
        stdinWriter.Write(New Byte() {&H48, &H65, &H6C, &H6C, &H6F, &H21})
      End Using ' 子プロセスの標準入力を閉じて書き込みを終了する

      Dim output As Byte()

      Using stdoutReader As New BinaryReader(stdout.BaseStream)
        ' 標準出力から最大16バイトのバイナリデータを読み込む
        output = stdoutReader.ReadBytes(16)
      End Using

      ' 子プロセスの終了を待機する
      child.WaitForExit()

      ' 読み込んだバイナリデータ文字列に変換して表示する
      Console.WriteLine(Encoding.ASCII.GetString(output))
    End Using
  End Sub
End Class

Imports System
Imports System.IO
Imports System.Security.Cryptography

Class Sample
  Shared Sub Main()
    ' 標準入力のStreamを取得
    Dim input As Stream = Console.OpenStandardInput()

    ' 標準出力のStreamをベースに、書き込まれる内容を
    ' BASE64エンコードするCryptoStreamを作成する
    Using output As New CryptoStream(
      Console.OpenStandardOutput(),
      New ToBase64Transform(),
      CryptoStreamMode.Write,
      leaveOpen := True
    )
      ' 入力ストリームの内容を出力ストリームに書き込む
      ' (BASE64エンコードされた上で書き込まれる)
      input.CopyTo(output)
    End Using
  End Sub
End Class