' Accountクラスの宣言
Class Account
  ' IDを格納するフィールド
  Public ID As Integer
  ' 名前を格納するフィールド
  Public Name As String
End Class

' クラスC1の宣言
Class C1
End Class

' クラスC2の宣言
Class C2
End Class

' 構造体S1の宣言
Structure S1
End Structure

Imports System

' クラス(宣言)
Class Account
  Public ID As Integer
  Public Name As String
End Class

Module Sample
  Sub Main()
    Dim alice As Account ' クラス型変数

    alice.ID = 1
    alice.Name = "Alice"
  End Sub
End Module

ハンドルされていない例外 : System.NullReferenceException: オブジェクト参照がオブジェクト インスタンスに設定されていません。
   at Sample.Main() in E:\sample.vb:line 12

Imports System

Class Account
  Public ID As Integer
  Public Name As String
End Class

Module Sample
  Sub Main()
    Dim alice As Account

    ' 新たにAccountクラスのインスタンスを作成し、変数aliceへ代入
    alice = New Account()

    ' 作成したインスタンスに対して操作を行う
    alice.ID = 1
    alice.Name = "Alice"
  End Sub
End Module

' 変数aliceを宣言し、Accountクラスのインスタンスを作成して代入する
Dim alice As Account = New Account()

alice.ID = 1
alice.Name = "Alice"

' 変数aliceを宣言し、Accountクラスのインスタンスを作成して代入する
Dim alice As New Account()

alice.ID = 1
alice.Name = "Alice"

Imports System

Class Account
  Public ID As Integer
  Public Name As String
End Class

Module Sample
  Sub Main()
    ' 変数aliceを宣言し、Accountクラスのインスタンスを作成して代入する
    Dim alice As New Account()

    alice.ID = 1
    alice.Name = "Alice"

    Console.WriteLine("ID = {0}, Name = {1}", alice.ID, alice.Name)
  End Sub
End Module

ID = 1, Name = Alice

Imports System

Class Account
  ' 内部的にIDを保持するためのフィールド
  Private _ID As Integer
  ' 内部的に名前を保持するためのフィールド
  Private _Name As String

  ' Newという名前のメソッドはコンストラクタとして扱われる
  Public Sub New(ByVal id As Integer, ByVal name As String)
    _ID = id
    _Name = name
  End Sub

  ' クラスでは引数を取らないコンストラクタを作成することができる
  Public Sub New()
    _ID = 0
    _Name = "(default)"
  End Sub

  ' 次のような宣言により、クラスにプロパティを持たせることもできる
  Public Property ID() As Integer
    Get
      ' プロパティを介して返される値を返す
      Return _ID
    End Get
    Set(ByVal Value As Integer)
      ' プロパティを介して設定される値を保持する
      _ID = Value
    End Set
  End Property

  Public Property Name() As String
    Get
      Return _Name
    End Get
    Set(ByVal Value As String)
      _Name = Value
    End Set
  End Property

  ' メソッドを持たせることができるほか、基底クラスのメソッドを
  ' オーバーライドして動作を変えることもできる
  Public Overrides Function ToString() As String
    Return "ID = " + _ID.ToString() + ", Name = " + _Name
  End Function
End Class

Module Sample
  Sub Main()
    ' コンストラクタにパラメータを指定しないでインスタンスを作成する
    Dim alice As New Account()

    ' プロパティの値を変更する
    alice.ID = 1
    alice.Name = "Alice"

    ' コンストラクタにパラメータを指定してインスタンスを作成する
    Dim bob As New Account(2, "Bob")

    ' コンストラクタにパラメータを指定してインスタンスを作成する
    Dim charlie As New Account(3, "Charlie")

    ' プロパティの値を変更する
    charlie.ID = 999

    ' ToStringメソッドを呼び出して文字列化して表示する
    Console.WriteLine(alice.ToString())
    Console.WriteLine(bob.ToString())

    ' Console.WriteLineは自動的にToStringを呼び出して文字列化することもできるので
    ' このようにしても同じ
    Console.WriteLine(charlie)
  End Sub
End Module

ID = 1, Name = Alice
ID = 2, Name = Bob
ID = 999, Name = Charlie

Imports System

Class Account
  ' 共有メンバ
  Private Shared Count As Integer = 0

  ' 非共有(インスタンス)メンバ
  Public ID As Integer
  Public Name As String

  Public Sub New()
    ' インスタンスが作成される度にCountをカウントアップする
    Count += 1
  End Sub

  ' 共有メソッド
  Public Shared Sub PrintCount()
    Console.WriteLine(Count)
  End Sub
End Class

Module Sample
  Sub Main()
    ' インスタンスを3つ作成する
    Dim alice As New Account()
    Dim bob As New Account()
    Dim charlie As New Account()

    ' インスタンスメンバの変更
    alice.ID = 1
    alice.Name = "Alice"

    ' 共有メソッドを呼び出して作成されたインスタンスの数を表示する
    Account.PrintCount()
  End Sub
End Module

3

Imports System

Class Sample
  ' アプリケーションのエントリポイント
  Shared Sub Main()
    Console.WriteLine("Hello, world!")
  End Sub
End Class

Imports System

Class Account
  Public Name As String
End Class

Module Sample
  Sub Main()
    ' コンストラクタにパラメータを指定しないでインスタンスを作成する
    Dim alice As New Account()

    ' インスタンスを使った処理
    alice.Name = "Alice"
    '    :
    '    :
    '    :

    ' インスタンスが不要になっても明示的に破棄する必要はない
  End Sub
End Module

Imports System

' 明示的な解放が必要になるリソースを扱うクラス
Class Resource
  ' IDisposableインターフェイスを実装する
  Implements IDisposable

  Public Sub Dispose() Implements IDisposable.Dispose
    ' リソースの解放処理を記述する
  End Sub
End Class

Module Sample
  Sub Main()

    ' Usingステートメント内でインスタンスを作成・使用することにより、
    ' Disposeメソッドによる解放処理が確実に実行されるようにする
    Using res As New Resource()
      ' リソースを使った処理
    End Using

  End Sub
End Module

Imports System

Class Resource
  Protected Overrides Sub Finalize()
    ' Finalizeメソッドをオーバーライドしてデストラクタを記述する場合は、
    ' 基底クラスのFinalizeメソッドも呼び出す必要がある
    MyBase.Finalize()
  End Sub
End Class

Module Sample
  Sub Main()
    Dim res As New Resource()

    ' このようにして直接デストラクタを呼び出すことはできない
    res.Finalize()
  End Sub
End Module

Imports System

Class Resource
  ' IDisposableインターフェイスを実装する
  Implements IDisposable

  ' IDisposableインターフェイスのメソッドDisposeを実装する
  Sub Dispose() Implements IDisposable.Dispose
    ' メソッド内の実装は省略
  End Sub
End Class

Imports System

Interface I1
  Sub Method()
End Interface

Interface I2
  Sub Method()
End Interface

Class C
  ' 二つのインターフェイスI1, I2を実装する
  Implements I1, I2

  ' I1インターフェイスのメソッドMethodを、M1という名前のメソッドとして実装する
  Sub M1() Implements I1.Method
  End Sub

  ' I2インターフェイスのメソッドMethodを、M2という名前のメソッドとして実装する
  Sub M2() Implements I2.Method
  End Sub
End Class

Imports System

' 型のコンテナとなるクラス
Class C
  ' 入れ子になったクラス
  Class NC
  End Class

  Sub M()
    ' 入れ子になったクラスのインスタンスを作成・使用する
    Dim nc As New NC()
  End Sub
End Class

Imports System

' フィールド宣言のみを含むクラス宣言
Partial Class Account
  Public ID As Integer
  Public Name As String
End Class

Imports System

' コンストラクタとメソッドの宣言を含むクラス宣言
Partial Class Account
  Public Sub New(ByVal id As Integer, ByVal name As String)
    Me.ID = id
    Me.Name = name
  End Sub

  Public Overrides Function ToString() As String
    Return "ID = " + ID.ToString() + ", Name = " + Name
  End Function
End Class

Module Sample
  Sub Main()
    Dim alice As New Account(1, "Alice")

    Console.WriteLine(alice)
  End Sub
End Module

ID = 1, Name = Alice