Imports System
Imports System.Globalization

Class Sample
  Shared Sub Main()
    Dim isoWeekDates = {
      New With {.year = 2020, .weekNumber = 1, .weekdayNumber = 1},                             ' 2020年・最初週・最初曜日
      New With {.year = 2020, .weekNumber = 42, .weekdayNumber = 5},                            ' 2020年・第42週・第5日
      New With {.year = 2020, .weekNumber = ISOWeek.GetWeeksInYear(2020), .weekdayNumber = 7},  ' 2020年・最終週・最終曜日
      New With {.year = 2021, .weekNumber = 1, .weekdayNumber = 1},                             ' 2021年・最初週・最初曜日
      New With {.year = 2021, .weekNumber = ISOWeek.GetWeeksInYear(2021), .weekdayNumber = 7}   ' 2021年・最終週・最終曜日
    }
    Dim ja As New CultureInfo("ja") ' 日本語のカルチャ

    For Each d In isoWeekDates
      Dim dayOfWeek As DayOfWeek = GetDayOfWeekFromISOWeekdayNumber(d.weekdayNumber) ' ISO曜日番号からDayOfWeek(曜日)に変換

      Console.Write(
        "ISO週暦 {0}年 第{1}週 第{2}日 ({3}) = ",
        d.year,
        d.weekNumber,
        d.weekdayNumber,
        ja.DateTimeFormat.DayNames(CInt(dayOfWeek)) ' 曜日名(ja/日本語)を取得
      )

      ' ISO週暦での日付(週年・週番号・曜日)をDateTimeに変換して表示する
      Dim dt As DateTime = ISOWeek.ToDateTime(d.year, d.weekNumber, dayOfWeek)

      Console.WriteLine(dt.ToString("D", ja)) ' DateTimeを日付のみ・長い形式(ja/日本語)で文字列化
    Next
  End Sub

  Shared Function GetDayOfWeekFromISOWeekdayNumber(ByVal weekdayNumber As Integer) As DayOfWeek
    Return If(weekdayNumber = 7, DayOfWeek.Sunday, CType(weekdayNumber, DayOfWeek)) ' 引数チェックは省略
  End Function
End Class

ISO週暦 2020年 第1週 第1日 (月曜日) = 2019年12月30日月曜日
ISO週暦 2020年 第42週 第5日 (金曜日) = 2020年10月16日金曜日
ISO週暦 2020年 第53週 第7日 (日曜日) = 2021年1月3日日曜日
ISO週暦 2021年 第1週 第1日 (月曜日) = 2021年1月4日月曜日
ISO週暦 2021年 第52週 第7日 (日曜日) = 2022年1月2日日曜日